瑞星杀毒软件完全卸载指南
的有关信息介绍如下：
为了真实的模拟卸载环境，我下载安装了瑞星杀毒软件进行研究体验，下面我详细说一下瑞星杀毒软件无法卸载的原因和如何卸载的指南，本文我们用最新版的瑞星杀毒软件v16进行卸载演示。
瑞星杀毒软件无法卸载的根本原因就是：瑞星软件部署系统被破坏了，那么你的瑞星软件将无法升级、无法修复、无法卸载！这就是卸载不了瑞星的原因！
另为温馨提示：瑞星杀毒软件为了防止被恶意程序卸载，是拒绝被第三方软件卸载的，切勿使用各种卫士、第三方软件卸载瑞星，否则只能是自讨苦吃！！！！
那什么是瑞星软件部署系统，我会在下面会有详细的介绍。
那什么是瑞星部署系统呢？
瑞星杀毒软件早在2010年以前。瑞星安装文件夹中的结构是这样的：
每一个瑞星产品安装文件夹中都有一个完全相同的升级、修复、卸载程序，磁盘空间浪费严重，同时，软件备份各自存在各自的文件夹里面，不便于统一管理。
2011年以后。瑞星安装文件夹中的结构是这样的：
瑞星产品将升级、修复、卸载程序独立出来，这样就只占一份空间，不会浪费磁盘空间了，将瑞星的软件备份放到里面，这样所有的瑞星软件都可以随时调用了。这样就便于统一管理了。
那为什么瑞星软件总会开机启动，而且禁止启动项以后仍然会开机启动？玄机就在瑞星部署系统里面，那是无法干掉的。
如果瑞星杀毒软件的界面是图一这个样子，那就是v16了，如果不是那就是图二的瑞星杀毒软件2011了。
先调出瑞星杀毒软件v16右键托盘菜单后点击软件升级升级为最新版有弹窗提示后向下看。
如图在开始菜单上选择修复瑞星杀毒软件。
在弹出界面上选择卸载瑞星杀毒软件。
然后我们点击卸载，看下一步，
这个我们就不抽奖了，直接选择放弃奖品卸载瑞星。
在这里我们选择右下角的卸载瑞星杀毒软件。
在这里看看图片上的验证码是那几个字直接点击下方的验证码就可以了。好我们看到正在卸载了。
好。在这里我们把两个勾打上后选择关闭重启电脑，重启完成后在开始菜单上选择控制面板。
在这里选择添加删除程序。
在这里找到瑞星软件部署系统后点击删除。
在这里选择是就可以了，在这里如果卸载完成后就可以了，卸载掉了别忘了回来点赞哦！如果还是无法卸载那就请看顽固卸载方法。
在桌面上新建一个txt文本，后来把下面这段代码保存为文本后看下一步。
@echo off
Setlocal enabledelayedexpansion
Mode con cols=50 lines=12
title 瑞星软件卸载程序
color 3f
cd /d %~dp0
pushd %~dp0
set V_now=1.3
cls
echo;
echo 欢迎使用: 瑞星软件维护程序 仅适用于个人版
echo;
echo 版本: %V_now% 更新日期: 2013/02/01
echo ------------------------------------------------
echo 温馨提示: 本程序采用瑞星自带的维护工具,
echo;
echo Today is ↓ 极大程度上保证了卸载后无残留
echo;
echo !date:~0,4!/!date:~5,2!/!date:~8,2! by hez2010
ping /n 3 127.1>nul
goto a
:a
cls
set /a NO.=0
Mode con cols=60 lines=26
echo;
echo 请选择需要维护的瑞星软件: ^(A 重新检测 Q 退出 U 在线更新^)
echo;
for /f "tokens=*" %%a in ('dir /a:d /b /q "%programfiles%\Rising\RSD\Backup"') do (
if /i "%%a"=="RIS" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星全功能安全软件&echo !NO.!. 瑞星全功能安全软件&echo;
if /i "%%a"=="RAV" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星杀毒软件&echo !NO.!. 瑞星杀毒软件&echo;
if /i "%%a"=="RFW" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星个人防火墙&echo !NO.!. 瑞星个人防火墙&echo;
if /i "%%a"=="RSA" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星安全助手&echo !NO.!. 瑞星安全助手&echo;
if /i "%%a"=="RSE" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星安全浏览器&echo !NO.!. 瑞星安全浏览器&echo;
if /i "%%a"=="RFB" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星账号保险柜&echo !NO.!. 瑞星账号保险柜&echo;
if /i "%%a"=="RAD" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星软件管家&echo !NO.!. 瑞星软件管家&echo;
if /i "%%a"=="RVD" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星加密盘&echo !NO.!. 瑞星加密盘&echo;
if /i "%%a"=="RAG" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星安全游戏&echo !NO.!. 瑞星安全游戏&echo;
if /i "%%a"=="RSD" set /a NO.+=1&set NO._!NO.!=%%a&set NO._2_!NO.!=瑞星软件部署系统&echo !NO.!. 瑞星软件部署系统&echo;
)
set Choose=~
set /p Choose=
if /i !Choose!==a goto a
if /i !Choose!==u goto Update
if /i !Choose!==q exit
if !Choose! leq 0 (
echo;
echo 无效的选项, 请重新输入 ^^!
ping /n 2 127.1>nul
goto a
)
if !Choose! gtr !NO.! (
echo;
echo 无效的选项, 请重新输入 ^^!
ping /n 2 127.1>nul
goto a
)
set Version=未知
set Up_Time=未知
if exist "%programfiles%\Rising\RSD\Backup\!NO._%Choose%!\CompsVer.inf" for /f "tokens=2 delims==" %%x in ('findstr "Version" "%programfiles%\Rising\RSD\Backup\!NO._%Choose%!\CompsVer.inf"') do set Version=%%x
if exist "%programfiles%\Rising\RSD\Backup\!NO._%Choose%!\CompsVer.inf" for /f "tokens=2 delims==" %%x in ('findstr "Time" "%programfiles%\Rising\RSD\Backup\!NO._%Choose%!\CompsVer.inf"') do set Up_Time=%%x
cls
echo;
echo 您已选定的项目: !NO._2_%Choose%!
echo;
echo 当前版本: !Version!
echo;
echo 发布时间: !Up_Time!
echo;
if /i !NO._%Choose%!==RSD if /i !NO.!==1 echo C 卸载 其他键返回
if /i not !NO._%Choose%!==RSD echo A 修复 B 添加/删除功能 C 卸载 其他键返回
if /i !NO._%Choose%!==RSD if /i not !NO.!==1 echo 请先卸载其他瑞星软件, 任意键返回
echo;
if /i !NO._%Choose%!==RSD if /i not !NO.!==1 pause>nul&goto a
set Choose_=~
set /p Choose_=
if /i not "%Choose_%"=="a" if /i not "%Choose_%"=="b" if /i not "%Choose_%"=="c" goto a
if /i "%Choose_%"=="c" (
cls
echo;
echo 正在启动瑞星卸载程序, 请稍等...
echo;
echo 参数: /UNINSTALL /PRODUCT=!NO._%Choose%!
start /wait "" "%Programfiles%\Rising\RSD\Setup.exe" /UNINSTALL /PRODUCT=!NO._%Choose%!
echo;
echo 正在处理, 请稍等...
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"|findstr /i "!NO._%Choose%!" 2>nul
if !errorlevel!==1 (
cls
echo;
echo 您已选定的项目: !NO._2_%Choose%!
echo;
echo 当前版本: !Version!
echo;
echo 发布时间: !Up_Time!
echo;
echo 卸载成功
echo;
if exist "%Programfiles%\Rising\RSD\Backup\!NO._%Choose%!" echo 是否重新启动您的计算机? [Y/N]
echo;
if exist "%Programfiles%\Rising\RSD\Backup\!NO._%Choose%!" set cq=~
if exist "%Programfiles%\Rising\RSD\Backup\!NO._%Choose%!" set /p cq=
if exist "%Programfiles%\Rising\RSD\Backup\!NO._%Choose%!" if /i "%cq%"=="y" shutdown /r /t 0&exit
ping /n 2 127.1>nul
goto a
) else (
cls
echo;
echo 您已选定的项目: !NO._2_%Choose%!
echo;
echo 当前版本: !Version!
echo;
echo 发布时间: !Up_Time!
echo;
echo 卸载失败, 请重试卸载
echo;
ping /n 2 127.1>nul
goto a
))
if /i not "%Choose_%"=="c" (
cls
echo;
echo 正在启动瑞星维护程序, 请稍等...
echo;
echo 参数: /REPAIR /PRODUCT=!NO._%Choose%!
start /wait "" "%Programfiles%\Rising\RSD\Setup.exe" /REPAIR /PRODUCT=!NO._%Choose%!
echo;
echo 操作完成 ^^!
ping /n 2 127.1>nul
goto a
)
:Update
cls
echo.
echo 正在检查更新, 请稍等...
echo.
ping /n 1 kafan.cn>nul
if %errorlevel%==1 echo 网络异常&ping /n 2 127.1>nul&goto a
echo Set Web_Download = CreateObject("Microsoft.XMLHTTP") >"%temp%\Web_Download.vbs"
echo Web_Download.Open "GET",Wscript.Arguments.Item(0),0 >>"%temp%\Web_Download.vbs"
echo Web_Download.Send() >>"%temp%\Web_Download.vbs"
echo Set Web_Save = CreateObject("ADODB.Stream") >>"%temp%\Web_Download.vbs"
echo Web_Save.Mode = 3 >>"%temp%\Web_Download.vbs"
echo Web_Save.Type = 1 >>"%temp%\Web_Download.vbs"
echo Web_Save.Open() >>"%temp%\Web_Download.vbs"
echo Web_Save.Write(Web_Download.responseBody) >>"%temp%\Web_Download.vbs"
echo Web_Save.SaveToFile Wscript.Arguments.Item(1),2 >>"%temp%\Web_Download.vbs"
cscript //NoLogo /e:vbscript "%temp%\Web_Download.vbs" "http://bbs.kafan.cn/thread-1442318-1-1.html" 2>nul "%temp%\Up.dat"
set V_new=?
if exist "%temp%\Up.dat" (
FOR /F "delims=（" %%u IN ('findstr "（程序版本）" "%temp%\Up.dat"') DO set V_new=%%u
FOR /F "delims=（" %%d IN ('findstr "（发布日期）" "%temp%\Up.dat"') DO set D_new=%%d
)
if !V_new!==? echo 网络异常&ping /n 2 127.1>nul&goto a
if not %V_now%==!V_new! call :Up
if %V_now%==!V_new! echo 已是最新&ping /n 2 127.1>nul&goto a
goto a
:Up
cls
echo.
echo 发现新版本:
echo.
echo 版本: !V_new!, 发布日期: !D_new!
echo.
echo A 更新 B 查看 其他键返回
echo.
set up=~
set /p up=
if /i "%up%"=="a" goto Updating
if /i "%up%"=="b" start "" "http://bbs.kafan.cn/thread-1442318-1-1.html"
goto :eof
:Updating
cls
echo.
echo 正在由旧版本 %V_now% 升级至新版本 !V_new!
echo.
echo 正在下载...
echo open ftp.byethost17.com>"%temp%\ftp.txt"
echo b17_12047896>>"%temp%\ftp.txt"
echo 2013hez>>"%temp%\ftp.txt"
echo cd "htdocs">>"%temp%\ftp.txt"
echo bin>>"%temp%\ftp.txt"
echo get "r_u_!V_new!.bat">>"%temp%\ftp.txt"
echo bye>>"%temp%\ftp.txt"
ftp -s:"%temp%\ftp.txt" >nul
del /f /q "%temp%\ftp.txt" >nul 2>nul
echo.
if exist "r_u_!V_new!.bat" echo 下载完成, 将重启程序并自动更新文件&ping /n 2 127.1>nul
if not exist "r_u_!V_new!.bat" echo 下载失败&ping /n 2 127.1>nul&goto a
move /y r_u_!V_new!.bat "%temp%\r_u_!V_new!.bat" >nul 2>nul
echo.
echo @echo off>"%temp%\更新.bat"
echo Mode con cols=50 lines=10>>"%temp%\更新.bat"
echo Color 3F>>"%temp%\更新.bat"
echo Title 在线更新>>"%temp%\更新.bat"
echo echo;>>"%temp%\更新.bat"
echo echo;>>"%temp%\更新.bat"
echo echo;>>"%temp%\更新.bat"
echo echo;>>"%temp%\更新.bat"
echo echo ...正在更新...>>"%temp%\更新.bat"
echo ping /n 3 127.1^>nul>>"%temp%\更新.bat"
echo move /y "%temp%\r_u_!V_new!.bat" 瑞星软件维护程序.bat^>nul 2^>nul>>"%temp%\更新.bat"
echo start "" "瑞星软件维护程序.bat">>"%temp%\更新.bat"
echo exit>>"%temp%\更新.bat"
start "" "%temp%\更新.bat"
exit
然后把后缀改为".bat"保存就可以了。
具体操作请看视频教程，就可以了。
